从Access中获取记录

Question

我有这个需求，我必须根据其他字段中给出的数据检查数据。我有'N'字段的桌子。我应该允许用户从表中选择4个字段。然后，我应该得到该特定记录的所有其他字段，并将其显示给用户，以便他可以验证他输入到表中的数据是否正确。请帮忙。

感谢

Answer 1

我有一个更清晰的认识现在的你需要的东西 - 希望这是你所需要的：

---

假设你有一个名为“手机”

的电话表的表有三个主要字段：制造商，操作系统和运营商 除了这些主要字段，还有辅助“规范”字段。现在我们有三个：ScreenSize，Frequencies和Price。

我创建了一个包含三个组合框的表单：ManufacturerFilter，OperatingSystemFilter和CarrierFilter。
每个组合框的行来源是类似于：

SELECT Carrier FROM Phones GROUP BY Carrier ORDER BY Carrier; 

当载流子是由制造商和[操作系统]分别取代。

然后我添加所有的次要字段，每个次要字段绑定到他们各自的字段。

您还可以添加一个名为“检索”的按钮，现在让点击代码留空。

---

此时您有几个选项。我还是要强调两个，而这两个选项都需要下面的过程：

Private Function FilterStr() As String 
    Dim myFilterStr As String 

    ' Include each filter if they are entered 
    If Nz(Me.ManufacturerFilter, "") <> "" Then myFilterStr = myFilterStr & "[Manufacturer]='" & Me.ManufacturerFilter.Value & "' AND" 
    If Nz(Me.OperatingSystemFilter, "") <> "" Then myFilterStr = myFilterStr & "[Operating System]='" & Me.OperatingSystemFilter.Value & "' AND" 
    If Nz(Me.CarrierFilter, "") <> "" Then myFilterStr = myFilterStr & "[Carrier]='" & Me.CarrierFilter.Value & "' AND" 

    ' Remove the last AND statement 
    If myFilterStr <> "" Then myFilterStr = Mid(myFilterStr, 1, Len(myFilterStr) - 4) 
    FilterStr = myFilterStr 
End Function 

这个函数返回一个过滤字符串，根据选择的组合框的选项。

选项＃1：筛选记录 我们希望发生什么，是当选择了主字段值，记录被过滤只有符合标准来显示。下面的代码添加到您的检索按钮的OnClick事件：

Private Sub RetreiveButton_Click() 
    Dim myFilterStr As String 
    myFilterStr = FilterStr 

    If myFilterStr <> "" Then 
    Me.Filter = myFilterStr 
    Me.FilterOn = True 
    Else 
    Me.Filter = "" 
    Me.FilterOn = False 
    End If 
End Sub 

所以单击按钮时会发生什么情况，是一个过滤字符串是基于选择的价值创造，然后过滤器被应用到形成。如果在组合框中未选择任何值，则会清除并关闭过滤器。

选项＃2：查找基于价值一个记录 我们要的是在组合框来选择值，然后移动到符合条件的记录。

将以下代码添加到检索按钮的onClick事件中。

Private Sub RetreiveButton_Click() 
    Dim rst As DAO.Recordset 
    Dim myFilterStr As String 

    myFilterStr = FilterStr() 

    If myFilterStr = "" Then 
    MsgBox "No Filter Selected", vbOKOnly, "Error" 
    Exit Sub 
    End If 

    Set rst = Me.RecordsetClone 
    rst.FindFirst myFilterStr 
    If rst.NoMatch Then 
    MsgBox "No Matching Records were found", vbOKOnly, "No Data" 
    Else 
    Me.Bookmark = rst.Bookmark 
    End If 

    Set rst = Nothing 
End Sub 

这使用相同的FilterStr（）函数来返回搜索字符串，但使用记录集的FindFirst方法来查找记录。如果找到，它将移动到记录。

希望能回答你的问题。正如我所指出的那样，确切的行为会有所不同，但其基本原则仍然是一样的。