需要具有相同大小的余弦相似度向量

Question

我想计算需要X，Y，Z技能的开放角色与W，T，L专业知识水平（熟练程度）和不同员工之间的相似程度......但并非全部员工将拥有所有的X，Y，Z技能，所以如果技能不存在，我们需要设置一个0 .... 我有什么是不工作的，因为当角色和员工都有技能。任何想法？在此先感谢

MATCH (p1:Employee)-[x:HAS_SKILL]->(sk:Personal_Skill)<-[y:REQUIRES_SKILL] -(p2:Role {name:'Role 1-Analytics Manager'}) 
WITH SUM(x.proficiency * y.proficiency) AS xyDotProduct, 
SQRT(REDUCE(xDot = 0.0, a IN COLLECT(x.proficiency) | xDot + a^2)) AS xLength, 
SQRT(REDUCE(yDot = 0.0, b IN COLLECT(y.proficiency) | yDot + b^2)) AS yLength, 
p1, p2 
MERGE (p1)-[s:SIMILARITY]-(p2) 
SET s.similarity = xyDotProduct/(xLength * yLength) 
RETURN p1.name, s.similarity 

Answer 1

这一个关键是你匹配分手成任意的MATCH的几个，使用方法和使用COALESCE（）来得到一个空的默认值。

第一步是匹配角色所需的所有技能。

接下来是MATCH对所有员工。

最后是一个从员工到技能的可选匹配，如果员工不具备该技能，这将为我们提供HAS_SKILL关系的空值。

从那里，我们得到的熟练程度，使用COALESCE（）默认为0，其中HAS_SKILL为空。

MATCH (sk:Personal_Skill)<-[y:REQUIRES_SKILL] -(p2:Role {name:'Role 1-Analytics Manager'}) 
MATCH (p1:Employee) 
OPTIONAL MATCH (p1)-[x:HAS_SKILL]->(sk) 
WITH p1, COALESCE(x.proficiency, 0) as xProf, y.proficiency as yProf, p2 
WITH SUM(xProf * yProf) AS xyDotProduct, 
SQRT(REDUCE(xDot = 0.0, a IN COLLECT(xProf) | xDot + a^2)) AS xLength, 
SQRT(REDUCE(yDot = 0.0, b IN COLLECT(yProf) | yDot + b^2)) AS yLength, 
p1, p2 
MERGE (p1)-[s:SIMILARITY]-(p2) 
SET s.similarity = xyDotProduct/(xLength * yLength) 
RETURN p1.name, s.similarity