sort_by函数如何工作？

Question

基于this的帖子，我想了解sort_by如何在JSON::PP中工作。

当运行该代码

#!/usr/bin/perl 
use strict; 
use warnings; 
use JSON::PP; 
use Data::Dumper qw(Dumper); 

my $h = { 
    22 => { title => "c", name => "d" }, 
    1 => { title => "1", name => "a" }, 
    10 => { title => "a", name => "c" }, 
    5 => { title => "b", name => "b" }, 
}; 

my $sorter = sub { 
    # See what's going on. 
    print "$JSON::PP::a cmp $JSON::PP::b\n"; 
    print Dumper(\@_, $_); 
    <STDIN>; # press return to continue 

    $JSON::PP::a cmp $JSON::PP::b 
}; 

my $js = JSON::PP->new; 
my $output = $js->sort_by($sorter)->encode($h); 
print $output . "\n"; 

它第一排序的内密钥，然后将外键，其确定在JSON字符串的最后顺序。

现在它输出

{"1":{"name":"a","title":"1"},"10":{"name":"c","title":"a"},"22":{"name":"d","title":"c"},"5":{"name":"b","title":"b"}} 

什么，我想直到结束的是，它是由title即排序。

{"1":{"name":"a","title":"1"},"5":{"name":"b","title":"b"}"10",{"name":"c","title":"a"},"22":{"name":"d","title":"c"}} 

我想第一个问题是禁用最后一个outter键排序？

那么我该如何获得title的价值？算法运行时，$JSON::PP::a和$JSON::PP::b包含来自相同散列的值name和title。

这我想不通。任何人都可以解释这一点，和/或帮我写这个算法？

Answer 1

你不能，或者至少不容易。您给sort_by的功能只能访问正在排序的键。为了做你想做的事，你需要访问与这些键相关的值（或者更可能的是，键所属的hashref，以便你可以自己查找这些值）。这似乎是一个有益的增强;您可能会提交功能请求。

如果您的数据结构足够简单（您的示例似乎是），那么您可以自己保留对散列的引用。为了做到这一点，你必须能够区分内部哈希中的键和外部哈希中的键（这样你就知道哪个哈希正在被排序，从而进行什么样的比较）。

my $sorter = sub { 
    if ($JSON::PP::a =~ /^\d+$/) { 
     return $h->{$JSON::PP::a}{title} cmp $h->{$JSON::PP::b}{title}; 
    } 
    return $JSON::PP::a cmp $JSON::PP::b 
}; 

Answer 2

尝试类似：

my $sorter = sub { 
    my $h = $_[0]; 

    # simple check for if we are too deep 
    # just sort by keys in that case 
    return $JSON::PP::a cmp $JSON::PP::b 
     if ref($h->{$JSON::PP::a}) ne 'HASH'; 

    # sort by titles value 
    return $h->{$JSON::PP::a}{title} cmp $h->{$JSON::PP::b}{title}; 
}; 

$_[0]目前正在整理散，本书虽然这似乎并没有被记录（因此可能是不可靠的）。

它适用于这种情况，但更复杂的结构会有问题，因为深度检查非常简单。如果你确定不存在这种类型的更深的键，那么对cjm这样的键类型的检查会更好。或者组合，如：

my $sorter = sub { 
    my $h = $_[0]; 

    # just sort by the keys 
    return $JSON::PP::a cmp $JSON::PP::b 
     unless $JSON::PP::a =~ /^\d+\z/ 
      && $JSON::PP::b =~ /^\d+\z/ 
      && ref($h->{$JSON::PP::a}) eq 'HASH' 
      && ref($h->{$JSON::PP::b}) eq 'HASH'; 

    # sort by titles 
    return $h->{$JSON::PP::a}{title} cmp $h->{$JSON::PP::b}{title}; 
};