glsl通过几何着色器问题

Question

此时我有一个工作顶点和片段着色器。如果我完全删除了几何着色器，那么我将在每个顶点获得具有颜色的期望立方体。但是添加了几何着色器后，几乎不显示几何图形。

顶点着色器：

#version 330 core 

layout(location = 0) in vec3 vertexPosition_modelspace; 
layout(location = 1) in vec3 vertexColor; 

out VertexData 
{ 
    vec3 color; 
} vertex; 

uniform mat4 MVP; 

void main(){  

    gl_Position = MVP * vec4(vertexPosition_modelspace,1); 
    vertex.color = vertexColor; 
} 

几何着色器：

#version 330 

precision highp float; 

in VertexData 
{ 
    vec3 color; 
} vertex[]; 

out vec3 fragmentColor; 

layout (triangles) in; 
layout (triangle_strip) out; 
layout (max_vertices = 3) out; 

void main(void) 
{ 
    for (int i = 0; i > gl_in.length(); i++) { 

     gl_Position = gl_in[i].gl_Position; 
     fragmentColor = vertex[i].color; 
     EmitVertex(); 
    } 

    EndPrimitive(); 
} 

片段着色器：

#version 330 core 

in vec3 fragmentColor; 

out vec3 color; 

void main(){ 
    color = fragmentColor; 
} 

我的显卡支持OpenGL 3.3，从我可以告诉。正如我所说。它没有几何着色器。作为数据，我传入两个GLfloat数组，每个数组都是顶点或顶点颜色。

Answer 1

for (int i = 0; i > gl_in.length(); i++) //note the '>' 

这个循环条件从一开始就是错误的，所以你永远不会发射任何顶点。你最可能的意思是i < gl_in.length()。