列表不等式约束

我正在尝试编写一个Prolog（CLP）谓词来构建约束两个列表不等式的约束。列表不等式约束

更正式的，有两个名单A=[A1,...,AN], B=[B1,...,BN]约束被定义为(A1 #\= B1) #\/ (A2 #\= B2) #\/ ... #\/ (AN #\= BN)。

我不确定如何建立这个约束给出两个任意长度的列表。这是我的尝试。我明白为什么它不起作用，但无法修复它。

any_different([], []). 
any_different([H1|T1], [H2|T2]):- 
    H1 #\= H2 #\/ any_different(T1, T2).

来源

2012-12-22 mscavnicky

你想建立的脱节，并通过第三个参数返回它：

any_different([], [], V) :- 
    V #= 0. % no differences between [] and [] 
any_different([H1|T1], [H2|T2], Disj) :- 
    any_different(T1, T2, Disj0), 
    Disj #<==> (H1 #\= H2) #\/ Disj0.

现在，调用any_different(List1, List2, AnyDiff) contrains变量AnyDiff可以传递到贴标谓词连同您的其他变量。通过说明AnyDiff #= 0，您可以将List1和List2限制为相等，而AnyDiff #= 1将导致它们不相等。

来源

2012-12-22 13:12:57

谢谢。这是我正在寻找的成语。 – mscavnicky

我认为，至少在SWI-Prolog的，谓词DIF/2和库（clpfd）可能是物化的选择：

?- L=[X,Y,Z], L ins 1..3, dif(L,[1,2,3]), label(L). 
L = [1, 1, 1], 
X = Y, Y = Z, Z = 1 ; 
L = [1, 1, 2], 
X = Y, Y = 1, 
Z = 2 ; 
...

来源

2012-12-23 11:33:59 CapelliC

下面是基于sum/3和clpfd物化(#<==>)/2实现：

not_equals_reified(X, Y, B) :- 
    X #\= Y #<==> B. 

any_different(Xs, Ys) :- 
    maplist(not_equals_reified, Xs, Ys, Bs), 
    sum(Bs, #>, 0).

使用meta-predicate maplist/4我们甚至都不需要编写递归代码！

来源

2015-04-09 09:09:00 repeat

列表不等式约束

回答

相关问题