OpenGL：调试“单通线框渲染”

Question

我试图实现“单通线框渲染”这个文件，这看起来很简单，但它给了我所期望的厚度，黑暗的值。

该文件没有给出确切的代码来找出高度，所以我做了它，因为我认为合适。代码应该将三个顶点投影到视口空间中，获取它们的“高度”并将它们发送给片段着色器。

片段着色器确定最近边缘的距离并生成edgeIntensity。我不确定我应该怎样处理这个值，但是因为它应该在[0,1]之间进行缩放，所以我将反转与我的输出颜色相乘，但它非常弱。

我有几个问题，我不确定在论文中提到。首先，应该用2D而不是3D来计算海拔高度？其次，他们使用DirectX功能，DirectX具有不同的视口空间z范围，是否正确？这很重要吗？我将视出口高度距离乘以视口空间坐标的w值，因为他们建议对透视投影进行校正。

image trying to correct for perspective projection

no correction (not premultiplying by w-value)

非校正的图像好像还没有修正的更远，面对的侧面透视清晰的问题，但角度校正一个具有非常弱的值。

任何人都可以看到我的代码有什么问题，或者如何从这里进行调试？

在GLSL我的顶点代码...

float altitude(in vec3 a, in vec3 b, in vec3 c) { // for an ABC triangle 
    vec3 ba = a - b; 
    vec3 bc = c - b; 
    vec3 ba_onto_bc = dot(ba,bc) * bc; 
    return(length(ba - ba_onto_bc)); 
} 

in vec3 vertex; // incoming vertex 
in vec3 v2; // first neighbor (CCW) 
in vec3 v3; // second neighbor (CCW) 
in vec4 color; 
in vec3 normal; 
varying vec3 worldPos; 
varying vec3 worldNormal; 
varying vec3 altitudes; 
uniform mat4 objToWorld; 
uniform mat4 cameraPV; 
uniform mat4 normalToWorld; 
void main() { 
    worldPos = (objToWorld * vec4(vertex,1.0)).xyz; 
    worldNormal = (normalToWorld * vec4(normal,1.0)).xyz; 
    //worldNormal = normal; 
    gl_Position = cameraPV * objToWorld * vec4(vertex,1.0); 
    // also put the neighboring polygons in viewport space 
    vec4 vv1 = gl_Position; 
    vec4 vv2 = cameraPV * objToWorld * vec4(v2,1.0); 
    vec4 vv3 = cameraPV * objToWorld * vec4(v3,1.0); 
    altitudes = vec3(vv1.w * altitude(vv1.xyz,vv2.xyz,vv3.xyz), 
        vv2.w * altitude(vv2.xyz,vv3.xyz,vv1.xyz), 
        vv3.w * altitude(vv3.xyz,vv1.xyz,vv2.xyz)); 
    gl_FrontColor = color; 
} 

和我的片段代码...

varying vec3 worldPos; 
varying vec3 worldNormal; 
varying vec3 altitudes; 
uniform vec3 cameraPos; 
uniform vec3 lightDir; 
uniform vec4 singleColor; 
uniform float isSingleColor; 
void main() { 
    // determine frag distance to closest edge 
    float d = min(min(altitudes.x, altitudes.y), altitudes.z); 
    float edgeIntensity = exp2(-2.0*d*d); 
    vec3 L = lightDir; 
    vec3 V = normalize(cameraPos - worldPos); 
    vec3 N = normalize(worldNormal); 
    vec3 H = normalize(L+V); 
    //vec4 color = singleColor; 
    vec4 color = isSingleColor*singleColor + (1.0-isSingleColor)*gl_Color; 
    //vec4 color = gl_Color; 
    float amb = 0.6; 
    vec4 ambient = color * amb; 
    vec4 diffuse = color * (1.0 - amb) * max(dot(L, N), 0.0); 
    vec4 specular = vec4(0.0); 
    gl_FragColor = (edgeIntensity * vec4(0.0)) + ((1.0-edgeIntensity) * vec4(ambient + diffuse + specular)); 
} 

Answer 1

第一，你的函数的高度（）是有缺陷的，ba_onto_bc计算因为bc不是单位长度（要么将bc归一化，要么将ba_onto_bc除以长度平方的点（bc，bc） - 这样可以节省计算平方根的时间）。

如果您想要恒定厚度的边缘，则应该用2D来计算海拔高度;如果您想要透视正确的边缘，则用3D来计算海拔。使用重心坐标作为单独的顶点属性（即，三角形的顶点0将得到（1 0 0），第二顶点（0 1 0）和最后一个顶点（0 0））将会容易得多， 1））。在片段着色器中，您将计算最小值并使用step（）或smoothstep（）来计算边缘。

这只需要1个属性而不是当前的两个，它也可以避免在顶点着色器中计算高度的需要（尽管如果您想对预测重心的坐标进行预分级，但离线计算）。它也应该是非常快速的工作，所以这将是一个很好的起点，以达到预期的行为。

Answer 2

我已经实现猪的想法，结果是完美的，这里是我的截图：

struct MYBUFFEREDVERTEX { 
    float x, y, z; 
    float nx, ny, nz; 
    float u, v; 
    float bx, by, bz; 
}; 

const MYBUFFEREDVERTEX g_vertex_buffer_data[] = { 
    -1.0f, -1.0f, 0.0f, 
    0.0f, 0.0f, 1.0f, 
    0.0f, 0.0f, 
    1.0f, 0.0f, 0.0f, 

    1.0f, -1.0f, 0.0f, 
    0.0f, 0.0f, 1.0f, 
    1.0f, 0.0f, 
    0.0f, 1.0f, 0.0f, 

    -1.0f, 1.0f, 0.0f, 
    0.0f, 0.0f, 1.0f, 
    0.0f, 1.0f, 
    0.0f, 0.0f, 1.0f, 

    1.0f, 1.0f, 0.0f, 
    0.0f, 0.0f, 1.0f, 
    1.0f, 1.0f, 
    1.0f, 0.0f, 0.0f, 
}; 

glDrawArrays(GL_TRIANGLE_STRIP, 0, 4); 

顶点着色器：

#ifdef GL_ES 
// Set default precision to medium 
precision mediump int; 
precision mediump float; 
#endif 

uniform mat4 u_mvp_matrix; 
uniform vec3 u_light_direction; 

attribute vec3 a_position; 
attribute vec3 a_normal; 
attribute vec2 a_texcoord; 
attribute vec3 a_barycentric; 

varying vec2 v_texcoord; 
varying float v_light_intensity; 
varying vec3 v_barycentric; 

void main() 
{ 
    // Calculate vertex position in screen space 
    gl_Position = u_mvp_matrix * vec4(a_position, 1.0); 
    // calculate light intensity, range of 0.3 ~ 1.0 
    v_light_intensity = max(dot(u_light_direction, a_normal), 0.3); 
    // Pass texture coordinate to fragment shader 
    v_texcoord = a_texcoord; 
    // Pass bary centric to fragment shader 
    v_barycentric = a_barycentric; 
} 

片段着色器：

#ifdef GL_ES 
// Set default precision to medium 
precision mediump int; 
precision mediump float; 
#endif 

uniform sampler2D u_texture; 

varying vec2 v_texcoord; 
varying float v_light_intensity; 
varying vec3 v_barycentric; 

void main() 
{ 
    float min_dist = min(min(v_barycentric.x, v_barycentric.y), v_barycentric.z); 
    float edgeIntensity = 1.0 - step(0.005, min_dist); 
    // Set diffuse color from texture 
    vec4 diffuse = texture2D(u_texture, v_texcoord) * vec4(vec3(v_light_intensity), 1.0); 
    gl_FragColor = edgeIntensity * vec4(0.0, 1.0, 1.0, 1.0) + (1.0 - edgeIntensity) * diffuse; 
}